5 DIM A$(1000,2),C$(40)
6 PRINT"[147]":POKE53280,3:POKE53281,3:POKE646,0
10 X=1
20 FORY=1TO2:READA$(X,Y)
30 IFA$(X,1)="*"THEN60
40 NEXT
50 X=X+1:GOTO20
60 X=X-1
70 :       FORT=1TOX:PRINTA$(T,1):NEXT
71 :
72 REM DIE ZEILE 70 IS NUR DAZU DA,
73 REM DASS DU SIEHST, WELCHE WORTE
74 REM IM PROGGI STEHEN...
75 :
80 POKE198,0:WAIT198,1:POKE198,0
100 F=INT(X*RND(1))+1
110 N=LEN(A$(F,1))
115 FORT=1TO40:C$(T)="":NEXT
120 FORO=1TON
130 H=INT(N*RND(1))+1
140 IFC$(H)<>""THEN130
150 C$(H)=MID$(A$(F,1),O,1)
160 NEXT
170 PRINT"[147]BILDE AUS FOLGENDEN BUCHSTABEN EIN WORT,"
180 PRINT"DAS DURCH DEN DANACH STEHENDEN BEGRIFF":PRINT"BESCHRIEBEN WIRD!"
190 PRINT"":FORT=1TON
200 PRINTC$(T);" ";
210 NEXT:PRINT
220 PRINT"";A$(F,2)
230 INPUT"DEINE ANTWORT ";D$
240 IFD$=A$(F,1)THENPRINT" RICHTIG ! [146]"
250 POKE198,0:WAIT198,1:POKE198,0
260 :
270 :
300 POKE19,64:INPUT"[147]GIB BITTE EIN WORT EIN : ";D$
305 POKE19,0:PRINT
310 FORT=1TOX
320 IFD$=A$(T,1)THENV=T:K=1:T=X
330 NEXT
340 IFK=1THENK=0:PRINT"";A$(V,1);" IST EIN(E) ";A$(V,2):GOTO360
350 PRINT"DIESES WORT KENNE ICH NICHT !"
360 POKE198,0:WAIT198,1:POKE198,0
370 :
380 :
500 PRINT"[147]             E D I T O R "
501 CLR  :DIMA$(100,2)
502 REM  ALLES WEGEN NEUEINGABE LOESCHEN
503 REM  IST NUR 'SICHERHEITSHALBER' -
504 REM  WEIL DAS GLEICHE ARRAY (A$)
505 REM  VERWENDET WIRD...
506 :
550 X=1
560 INPUT"GESUCHTES WORT ";A$(X,1)
565 IFA$(X,1)="_"THEN585
570 INPUT"ERKLAERUNGSWORT ";A$(X,2)
580 X=X+1:GOTO560
585 X=X-1
590 PRINT"[147] DATEI WIRD GESPEICHERT !":OPEN2,8,2,"TESTDATEI,S,W"
600 FORT=1TOX
610 PRINT#2,A$(T,1)
620 PRINT#2,A$(T,2)
630 NEXT
635 CLOSE2
640 PRINT"";X;"DATENSAETZE SIND GESPEICHERT!"
650 POKE198,0:WAIT198,1:POKE198,0
660 CLR:DIMA$(100,2):   REM  EINGEGEBENE DATEN FUER EINLESETEST LOESCHEN
661 :
662 :
700 PRINT"[147]               L A D E N"
710 OPEN2,8,2,"TESTDATEI,S,R"
720 X=1
730 INPUT#2,A$(X,1)
735 INPUT#2,A$(X,2)
740 IFST<>64THENX=X+1:GOTO730
750 CLOSE2
760 PRINT"";X;"DATEN SIND GELADEN !"
770 DIMC$(40):  GOTO70
771 REM    JETZT STARTET DAS PROGGI MIT            DEN VON DISK GELESENEN DATEN
1000 DATATASCHE,TRANSPORTMITTEL,BIER,GETRAENK,HOSE,KLEIDUNGSSTUECK,WASSER
1001 DATAFLUESSIGKEIT,GELD,ZAHLUNGSMITTEL,DISKETTE,COMPUTER-ZUBEHOER
1002 DATAZEITUNG,INFORMATIONS-MEDIUM,FENSTER,OEFFNUNG IN DER WAND,*
1999 :
2000 REM 'CLR' LOESCHT GRUNDSAETZLICH
2001 REM         A L L E S
2002 REM ALSO AUCH DIM-ENSIONIERUNGEN
2003 REM ETC. - DESHALB JEWEILS DIE
2004 REM   'NEU-DIM-ENSIONIERUNG'
2005 :
2006 REM        W I N N I